Change font size
It is currently Tue Jul 17, 2018 11:23 pm

Forum rules


{L_IMAGE}



Post a new topicPost a reply Page 1 of 2   [ 11 posts ]
Go to page 1, 2  Next
Author Message
 Post subject: Low Lag Snow(storm)
PostPosted: Sun Nov 20, 2011 4:40 pm 
OSG Elite

Joined: Wed Aug 05, 2009 1:59 am
Posts: 417
After rain (viewtopic.php?f=5&t=2767) and falling leaves (viewtopic.php?f=5&t=2897) we now have low lag snow.
This script can be used as a standalone script, or in a touch controlled system of linked prims. I'll show you how to build both versions.

I'll include a texture you can use for this script, you'll find it here.
Download it to your pc and upload it to your OSgrid avatar.

First the standalone version:
This version emits snow all the time. You have to delete it to stop the snow.

-Rez a prim, and make it transparent.
-Drag the texture 'Snowflakes' from your inventory into the content tab. <==IMPORTANT: If you do not do this, you'll see strange, glowing particles :)
-Open the content tab, and make a new script.
-Open the new script and replace the standard script with the script below.
-Save the script, and you'll be standing in snow within seconds.

{L_CODE}:
//// "Rain" PARTICLE TEMPLATE v1 - by Jopsy Pendragon - 4/8/2008

//// -> TEMPLATE CHANGED FOR FALLING LEAVES - by Haplo Voss - 11/2/2010 <-
//// -> TEMPLATE CHANGED FOR SNOW (LOW LAG) - by Oddball Otoole 11/20/2011 <-

//// You are free to use this script as you please, so long as you include this line:
//** The original 'free' version of this script came from THE PARTICLE LABORATORY. **//

// SETUP:  Drop one optional particle texture and this script into a prim.
// Particles should start automatically. (Reset) the script if you insert a
// particle texture later on.  Add one or more CONTROLLER TEMPLATES to any
// prims in the linked object to control when particles turn ON and OFF.

// Customize the particle_parameter values below to create your unique
// particle effect and click SAVE.  Values are explained along with their
// min/max and default values further down in this script.


string  CONTROLLER_ID = "A"; // See comments at end regarding CONTROLLERS.
integer AUTO_START = TRUE;   // Optionally FALSE only if using CONTROLLERS.

list particle_parameters=[]; // stores your custom particle effect, defined below.
list target_parameters=[]; // remembers targets found using TARGET TEMPLATE scripts.

default {
    state_entry() {
        particle_parameters = [  // start of particle settings
           // Texture Parameters:
           PSYS_SRC_TEXTURE, "Snowflakes",
           PSYS_PART_START_SCALE, <4,4, FALSE>,  PSYS_PART_END_SCALE, <5,5, FALSE>, 
           PSYS_PART_START_COLOR, <1,1,1>,      PSYS_PART_END_COLOR, <1,1,1>,
           PSYS_PART_START_ALPHA, (float)0.1,       PSYS_PART_END_ALPHA, (float)1.0,     
         
           // Production Parameters:
           PSYS_SRC_BURST_PART_COUNT, (integer)2,
           PSYS_SRC_BURST_RATE, (float) 0.025, 
           PSYS_PART_MAX_AGE, (float)15.0,
           PSYS_SRC_MAX_AGE,(float) 0.0, 
       
           // Placement Parameters:
           PSYS_SRC_PATTERN, (integer)8, // 1=DROP, 2=EXPLODE, 4=ANGLE, 8=ANGLE_CONE,
           
           // Placement Parameters (for any non-DROP pattern):
           PSYS_SRC_BURST_SPEED_MIN, (float)0.5,   PSYS_SRC_BURST_SPEED_MAX, (float)0.0,
           PSYS_SRC_BURST_RADIUS, 10.0,
       
           // Placement Parameters (only for ANGLE & CONE patterns):
           PSYS_SRC_ANGLE_BEGIN, (float) PI,   PSYS_SRC_ANGLE_END, (float)0.0*PI, 
        // PSYS_SRC_OMEGA, <0,0,0>,
       
           // After-Effect & Influence Parameters:
           PSYS_SRC_ACCEL, <0.0,0.0,-.8>, 
        // PSYS_SRC_TARGET_KEY,      llGetLinkKey(llGetLinkNum() + 1),       
             
           PSYS_PART_FLAGS, (integer)( 0         // Texture Options:     
                                | PSYS_PART_INTERP_COLOR_MASK   
                                | PSYS_PART_INTERP_SCALE_MASK   
                                | PSYS_PART_EMISSIVE_MASK   
                             // | PSYS_PART_FOLLOW_VELOCITY_MASK
                                                  // After-effect & Influence Options:
                                | PSYS_PART_WIND_MASK           
                             //   | PSYS_PART_BOUNCE_MASK         
                             // | PSYS_PART_FOLLOW_SRC_MASK     
                             // | PSYS_PART_TARGET_POS_MASK     
                             // | PSYS_PART_TARGET_LINEAR_MASK   
                            )
            //end of particle settings                     
        ];
       
        if ( AUTO_START ) llParticleSystem( particle_parameters );
       
    }
   
    link_message( integer sibling, integer num, string mesg, key target_key ) {
        if ( mesg != CONTROLLER_ID ) { // this message isn't for me.  Bail out.
            return;
        } else if ( num == 0 ) { // Message says to turn particles OFF:
            llParticleSystem( [ ] );
        } else if ( num == 1 ) { // Message says to turn particles ON:
            llParticleSystem( particle_parameters + target_parameters );
        } else if ( num == 2 ) { // Turn on, and remember and use the key sent us as a target:
            target_parameters = [ PSYS_SRC_TARGET_KEY, target_key ];
            llParticleSystem( particle_parameters + target_parameters );
        } else { // bad instruction number
            // do nothing.
        }           
    }
       
}


//============================= About Parameters =============================
// There are 22-ish NAMED attributes that affect a particle display.
// To customize a display you give each a VALUE.
// For example: PSYS_PART_START_COLOR is a named attribute,
// and <1.0, 0.5, 0.0> is a color VALUE (orange, in this case).
//
// As long as your 'names' and 'values' are paired up properly, they can
// be in any order!  Any you omit a pair, it reverts to a default value.

//============================= Texture Parameters =============================
//
// TEXTURE, can be an "Asset UUID" key copied from a texture
//          that you have full permissions to, or the name of
//          a texture in the prim's inventory.
//
// SCALE, (size) 0.0 to 4.0 meters wide, by 0.0 to 4.0 meters tall. (default 1x1)
//          Textures are FLAT, so the 'z' part of the vector is ignored.
//          Values smaller than 0.04x0.04 may not get rendered at all.
//          Tiny particles vanish if the viewer is not near them.
//
// BEGIN_SCALE sets particle start size. 
// END_SCALE (end size) is ignored, if the INTERP_SCALE_MASK option is disabled.
//
// COLOR, < RED, GREEN, BLUE > from <0.00,0.00,0.00> (black) to <1.00,1.00,1.00> (white/default)
// ALPHA, 1.0 = 100% visible(default), 0.0 = invisible.  Less than 0.1 might not get seen.
// START_COLOR and START_ALPHA set the color and transparency of newly created particles.
// END_COLOR and END_ALPHA are ignored, if the INTERP_COLOR_MASK option is disabled.
         
         
//============================= Production Parameters =============================
//
// BURST_PART_COUNT: quantity of particles per burst, 1 to 4096 (default 1),
//
// BURST_RATE: seconds to delay between particle bursts. 0.0 to 30.0 (default 0.1)
//
// PART_MAX_AGE: particle lifespan in seconds, 0.00 to 30.0 (default=10.0)
//               PART_MAX_AGE less than 0.5 might not be visible.
//
// The default total number of particles that can be seen is 4096, if one or more
// emitters try to create more than that, many will not be seen, and it may cause
// viewer lag.  Use as few particles as you can for your effect:
// AGE/RATE * COUNT will tell you approximately how many particles your emitter creates.
//
// SRC_MAX_AGE: emitter auto shut-off timer. 1.0 to 60.0 seconds. 0.0 = never stop. (default)


//============================= Placement Parameters =============================
//               
// PATTERN:   
//      DROP, ignores all other placement settings.
//      EXPLODE, spray particles in all directions
//      ANGLE, sprays a flat "fan" shape defined by ANGLE_BEGIN and END values
//      CONE, sprays "ring" or "cone" shapes defined by ANGLE_BEGIN and END values
//
// RADIUS:  0.0 to 50.0?  distance from emitter to create new particles
//      (RADIUS is disabled with DROP pattern and the FOLLOW_SRC & TARGET_LINEAR options)
//       
// SPEED: 0.00 to 50.0?  Sets min/max starting velocities for non-drop patterns. (default: 1.0)
//       
// ANGLE_BEGIN & END:  0.00*PI (up) to 1.00*PI (down),  (Only for ANGLE & CONE patterns)
//       (Values work much like the Sphere-prim's DIMPLE attributes.) (defaults: 0.0)
//
// OMEGA: <x,y,z> Sets how much to rotate angle/cone spray direction after
//                every burst. 0.0 to PI?  (default: <0,0,0>)

//======================== After-Effects & Influence Parameters ================
//
// ACCEL, x,y,z 0.0 to 50.0?  sets a constant force, (affects all patterns)
//          Causes particles to drift up/down or in a compass direction.
//          Use ACCEL to create the illusion of (anti-)gravity or a directional wind.
//          (ineffective with TARGET_LINEAR option)
//       
// TARGET_KEY,  "key", (requires the TARGET option be enabled). 
//       "key" can be a variety of many different things:
         // llGetOwner()
         // llGetKey() target self
         // llGetLinkKey(1) target parent prim
         // llGetLinkKey(llGetLinkNum() + 1) target next prim in link set
         //
         // WARNING: New copies of objects get new keys, you can't simply paste
         // a prim's key into your script and expect it to always work.  Visit
         // the Particle Laboratory's section on TARGETS for a variety of ways
         // to dynamically find your target's key. There are different 'best ways'
         // depending on if your target is linked to your emitter or not.


//============================= About Options =============================
//   
// Each option may be ON/ENABLED (no leading // )
// or OFF/DISABLED (by putting a // in front of it.)
// Options are combined together in a special way, (using the | symbol).
// This creates one single Parameter for PSYS_PART_FLAGS.

             
//============================= Texture Options =============================
//
// EMISSIVE: identical to "full bright" setting on prims     
//   
// FOLLOW_VELOCITY: particle texture 'tilts' towards the direction it's moving
//
// INTERP_COLOR: causes particle COLOR and ALPHA(transparency) to change over it's lifespan
//
// INTERP_SCALE: causes particle SCALE(size) to change over it's lifespan


//======================== After-Effects & Influences Options ================
//
// BOUNCE:  particles bounce up from the z-altitude of emitter, and cannot fall below it.
//
// WIND: the sim's wind will push particles around
//
// FOLLOW_SRC: makes particles move (but not rotate) if their emitter moves, (disables RADIUS)
//
// TARGET_POS: causes particles to arrive at a some target at end of of their lifespan.
//
// TARGET_LINEAR: forces particles to form into an even line from emitter to target
//                and forces a DROP-like pattern and disables effects of WIND and ACCEL



//========================================================================
//======================== USING CONTROL TEMPLATES =======================
//
// Want to control when your particles turn ON and OFF?   You can!
//
// Drop one (or more) of the CONTROL TEMPLATES from the particle laboratory
// into your object containing this script.  That's it!

// Your controls should be effective immediately.  (Some controllers can be
// adjusted and tuned, open them and read the USAGE notes to see.)
//
// One control template can control several particle templates in the
// same object.   (keep in mind that each prim can only have ONE
// particle effect active at a time).
//
// The 'particle_effect_name' value must be the same in both the control
// and particle template to work.  You can change that value and have
// a controller for one effect, and a different controller for a different
// effect in the same object.
//


//======================================== END ===============================


------------------------------------------------------------------
The Linked Prim System.
This system uses a start/stop prim to start/stop linked prims emitting snow.

-Rez a prim, and name it 'snow emitter'.
-Make it transparent.
-Drag the 'Snowflakes' texture from you inventory into the prims content. <==IMPORTANT: If you do not do this, you'll see strange, glowing particles :)
-Create a new script in this prim, name it Snow emitter. :)
-Replace the standard script with the 'Snow emitter' script below and save it.
-Now copy this prim as many times you need to cover the ares you want to let it snow. (This script let it snow in a 10m radius of the prim)
-Link all the snow emitters together.
-Now rez a new prim, and name it 'Snow Controller'. This prim should not be transparent, make it red or something. (Try clicking on something you can't see:) )
-Open the content tab, and create a new script, name this script 'Snow controller'.
-Replace the standard script with the 'Snow Controller' script below and save it.
-Find the linked snow emitter prims (CTRL-ALT-T lets you see transparent objects) and select them.
-Hold down the SHIFT-key and click on the 'Snow Controller' prim.
-Choose 'Link' or hit CTRL-L to link the 'Snow emitter' prims to the controller prim.

And your snow system is ready:)

The scripts:
'Snow emitter' script
{L_CODE}:
//// "Rain" PARTICLE TEMPLATE v1 - by Jopsy Pendragon - 4/8/2008

//// -> TEMPLATE CHANGED FOR FALLING LEAVES - by Haplo Voss - 11/2/2010 <-
//// -> TEMPLATE CHANGED FOR SNOW (LOW LAG) - by Oddball Otoole 11/20/2011 <-

//// You are free to use this script as you please, so long as you include this line:
//** The original 'free' version of this script came from THE PARTICLE LABORATORY. **//

// SETUP:  Drop one optional particle texture and this script into a prim.
// Particles should start automatically. (Reset) the script if you insert a
// particle texture later on.  Add one or more CONTROLLER TEMPLATES to any
// prims in the linked object to control when particles turn ON and OFF.

// Customize the particle_parameter values below to create your unique
// particle effect and click SAVE.  Values are explained along with their
// min/max and default values further down in this script.


string  CONTROLLER_ID = "A"; // See comments at end regarding CONTROLLERS.
integer AUTO_START = FALSE;   // Optionally FALSE only if using CONTROLLERS.

list particle_parameters=[]; // stores your custom particle effect, defined below.
list target_parameters=[]; // remembers targets found using TARGET TEMPLATE scripts.

default {
    state_entry() {
        particle_parameters = [  // start of particle settings
           // Texture Parameters:
           PSYS_SRC_TEXTURE, "Snowflakes",
           PSYS_PART_START_SCALE, <4,4, FALSE>,  PSYS_PART_END_SCALE, <5,5, FALSE>, 
           PSYS_PART_START_COLOR, <1,1,1>,      PSYS_PART_END_COLOR, <1,1,1>,
           PSYS_PART_START_ALPHA, (float)0.1,       PSYS_PART_END_ALPHA, (float)1.0,     
         
           // Production Parameters:
           PSYS_SRC_BURST_PART_COUNT, (integer)2,
           PSYS_SRC_BURST_RATE, (float) 0.025, 
           PSYS_PART_MAX_AGE, (float)15.0,
           PSYS_SRC_MAX_AGE,(float) 0.0, 
       
           // Placement Parameters:
           PSYS_SRC_PATTERN, (integer)8, // 1=DROP, 2=EXPLODE, 4=ANGLE, 8=ANGLE_CONE,
           
           // Placement Parameters (for any non-DROP pattern):
           PSYS_SRC_BURST_SPEED_MIN, (float)0.5,   PSYS_SRC_BURST_SPEED_MAX, (float)0.0,
           PSYS_SRC_BURST_RADIUS, 10.0,
       
           // Placement Parameters (only for ANGLE & CONE patterns):
           PSYS_SRC_ANGLE_BEGIN, (float) PI,   PSYS_SRC_ANGLE_END, (float)0.0*PI, 
        // PSYS_SRC_OMEGA, <0,0,0>,
       
           // After-Effect & Influence Parameters:
           PSYS_SRC_ACCEL, <0.0,0.0,-.8>, 
        // PSYS_SRC_TARGET_KEY,      llGetLinkKey(llGetLinkNum() + 1),       
             
           PSYS_PART_FLAGS, (integer)( 0         // Texture Options:     
                                | PSYS_PART_INTERP_COLOR_MASK   
                                | PSYS_PART_INTERP_SCALE_MASK   
                                | PSYS_PART_EMISSIVE_MASK   
                             // | PSYS_PART_FOLLOW_VELOCITY_MASK
                                                  // After-effect & Influence Options:
                                | PSYS_PART_WIND_MASK           
                             //   | PSYS_PART_BOUNCE_MASK         
                             // | PSYS_PART_FOLLOW_SRC_MASK     
                             // | PSYS_PART_TARGET_POS_MASK     
                             // | PSYS_PART_TARGET_LINEAR_MASK   
                            )
            //end of particle settings                     
        ];
       
        if ( AUTO_START ) llParticleSystem( particle_parameters );
       
    }
   
    link_message( integer sibling, integer num, string mesg, key target_key ) {
        if ( mesg != CONTROLLER_ID ) { // this message isn't for me.  Bail out.
            return;
        } else if ( num == 0 ) { // Message says to turn particles OFF:
            llParticleSystem( [ ] );
        } else if ( num == 1 ) { // Message says to turn particles ON:
            llParticleSystem( particle_parameters + target_parameters );
        } else if ( num == 2 ) { // Turn on, and remember and use the key sent us as a target:
            target_parameters = [ PSYS_SRC_TARGET_KEY, target_key ];
            llParticleSystem( particle_parameters + target_parameters );
        } else { // bad instruction number
            // do nothing.
        }           
    }
       
}


//============================= About Parameters =============================
// There are 22-ish NAMED attributes that affect a particle display.
// To customize a display you give each a VALUE.
// For example: PSYS_PART_START_COLOR is a named attribute,
// and <1.0, 0.5, 0.0> is a color VALUE (orange, in this case).
//
// As long as your 'names' and 'values' are paired up properly, they can
// be in any order!  Any you omit a pair, it reverts to a default value.

//============================= Texture Parameters =============================
//
// TEXTURE, can be an "Asset UUID" key copied from a texture
//          that you have full permissions to, or the name of
//          a texture in the prim's inventory.
//
// SCALE, (size) 0.0 to 4.0 meters wide, by 0.0 to 4.0 meters tall. (default 1x1)
//          Textures are FLAT, so the 'z' part of the vector is ignored.
//          Values smaller than 0.04x0.04 may not get rendered at all.
//          Tiny particles vanish if the viewer is not near them.
//
// BEGIN_SCALE sets particle start size. 
// END_SCALE (end size) is ignored, if the INTERP_SCALE_MASK option is disabled.
//
// COLOR, < RED, GREEN, BLUE > from <0.00,0.00,0.00> (black) to <1.00,1.00,1.00> (white/default)
// ALPHA, 1.0 = 100% visible(default), 0.0 = invisible.  Less than 0.1 might not get seen.
// START_COLOR and START_ALPHA set the color and transparency of newly created particles.
// END_COLOR and END_ALPHA are ignored, if the INTERP_COLOR_MASK option is disabled.
         
         
//============================= Production Parameters =============================
//
// BURST_PART_COUNT: quantity of particles per burst, 1 to 4096 (default 1),
//
// BURST_RATE: seconds to delay between particle bursts. 0.0 to 30.0 (default 0.1)
//
// PART_MAX_AGE: particle lifespan in seconds, 0.00 to 30.0 (default=10.0)
//               PART_MAX_AGE less than 0.5 might not be visible.
//
// The default total number of particles that can be seen is 4096, if one or more
// emitters try to create more than that, many will not be seen, and it may cause
// viewer lag.  Use as few particles as you can for your effect:
// AGE/RATE * COUNT will tell you approximately how many particles your emitter creates.
//
// SRC_MAX_AGE: emitter auto shut-off timer. 1.0 to 60.0 seconds. 0.0 = never stop. (default)


//============================= Placement Parameters =============================
//               
// PATTERN:   
//      DROP, ignores all other placement settings.
//      EXPLODE, spray particles in all directions
//      ANGLE, sprays a flat "fan" shape defined by ANGLE_BEGIN and END values
//      CONE, sprays "ring" or "cone" shapes defined by ANGLE_BEGIN and END values
//
// RADIUS:  0.0 to 50.0?  distance from emitter to create new particles
//      (RADIUS is disabled with DROP pattern and the FOLLOW_SRC & TARGET_LINEAR options)
//       
// SPEED: 0.00 to 50.0?  Sets min/max starting velocities for non-drop patterns. (default: 1.0)
//       
// ANGLE_BEGIN & END:  0.00*PI (up) to 1.00*PI (down),  (Only for ANGLE & CONE patterns)
//       (Values work much like the Sphere-prim's DIMPLE attributes.) (defaults: 0.0)
//
// OMEGA: <x,y,z> Sets how much to rotate angle/cone spray direction after
//                every burst. 0.0 to PI?  (default: <0,0,0>)

//======================== After-Effects & Influence Parameters ================
//
// ACCEL, x,y,z 0.0 to 50.0?  sets a constant force, (affects all patterns)
//          Causes particles to drift up/down or in a compass direction.
//          Use ACCEL to create the illusion of (anti-)gravity or a directional wind.
//          (ineffective with TARGET_LINEAR option)
//       
// TARGET_KEY,  "key", (requires the TARGET option be enabled). 
//       "key" can be a variety of many different things:
         // llGetOwner()
         // llGetKey() target self
         // llGetLinkKey(1) target parent prim
         // llGetLinkKey(llGetLinkNum() + 1) target next prim in link set
         //
         // WARNING: New copies of objects get new keys, you can't simply paste
         // a prim's key into your script and expect it to always work.  Visit
         // the Particle Laboratory's section on TARGETS for a variety of ways
         // to dynamically find your target's key. There are different 'best ways'
         // depending on if your target is linked to your emitter or not.


//============================= About Options =============================
//   
// Each option may be ON/ENABLED (no leading // )
// or OFF/DISABLED (by putting a // in front of it.)
// Options are combined together in a special way, (using the | symbol).
// This creates one single Parameter for PSYS_PART_FLAGS.

             
//============================= Texture Options =============================
//
// EMISSIVE: identical to "full bright" setting on prims     
//   
// FOLLOW_VELOCITY: particle texture 'tilts' towards the direction it's moving
//
// INTERP_COLOR: causes particle COLOR and ALPHA(transparency) to change over it's lifespan
//
// INTERP_SCALE: causes particle SCALE(size) to change over it's lifespan


//======================== After-Effects & Influences Options ================
//
// BOUNCE:  particles bounce up from the z-altitude of emitter, and cannot fall below it.
//
// WIND: the sim's wind will push particles around
//
// FOLLOW_SRC: makes particles move (but not rotate) if their emitter moves, (disables RADIUS)
//
// TARGET_POS: causes particles to arrive at a some target at end of of their lifespan.
//
// TARGET_LINEAR: forces particles to form into an even line from emitter to target
//                and forces a DROP-like pattern and disables effects of WIND and ACCEL



//========================================================================
//======================== USING CONTROL TEMPLATES =======================
//
// Want to control when your particles turn ON and OFF?   You can!
//
// Drop one (or more) of the CONTROL TEMPLATES from the particle laboratory
// into your object containing this script.  That's it!

// Your controls should be effective immediately.  (Some controllers can be
// adjusted and tuned, open them and read the USAGE notes to see.)
//
// One control template can control several particle templates in the
// same object.   (keep in mind that each prim can only have ONE
// particle effect active at a time).
//
// The 'particle_effect_name' value must be the same in both the control
// and particle template to work.  You can change that value and have
// a controller for one effect, and a different controller for a different
// effect in the same object.
//


//======================================== END ===============================


The 'Snow Controller' script.

{L_CODE}:
//// "Touch Toggle" CONTROLLER TEMPLATE v1 - by Jopsy Pendragon - 4/8/2008
//// You are free to use this script as you please, so long as you include this line:
//** The original 'free' version of this script came from THE PARTICLE LABORATORY. **//

// EFFECT: 'Touching' this prim will ACTIVATE or DEACTIVE particles.

// SETUP:  Drop this CONTROLLER TEMPLATE script into any prim of the same
// linked object as your PARTICLE TEMPLATE. It should be responsive immediately.

integer PLAY_SOUND = FALSE; // TRUE for a click-sound, FALSE for silent.
string  SOUND = "aa4c657c-ca31-4df2-8cee-aa324760f904"; // a click sound

string  CONTROLLER_ID = "A"; // see more about CONTROL TEMPLATES at end.

integer mode = 0; // keep track of whether particles are ON(1) or OFF(0).

default {
   
    touch_start(integer total_number) {
   
        if ( PLAY_SOUND ) llPlaySound( SOUND, 0.5 ); 
       
        mode = ! mode; // flip on to off, (or off to on).
       
        llMessageLinked( LINK_SET, mode, CONTROLLER_ID, NULL_KEY ); // send command
    }
   
    // Listen for other controllers sending ON/OFF commands and remember changes:
    link_message( integer sibling, integer num, string controller_id, key ignore ) {
       
        if ( controller_id != CONTROLLER_ID ) return; // this message is not for us.
       
        mode = num;
    }
}


//========================================================================
//======================== USING CONTROL TEMPLATES =======================
//
// By default one CONTROLLER TEMPLATE will activate and deactivate all the
// PARTICLE TEMPLATES that are in the same linked object.
//
// However, the templates will only obey or affect each other if they share
// identical CONTROLLER_ID's.
//
// If you want templates to operate independently, change the value for
// CONTROLLER_ID so that it is the same for all templates that work together.
// (and different from all the templates that it should ignore or be ignored by)

//==================================== END ===============================


Have fun!


Attachments:
Snowflakes.png
Snowflakes.png [ 135.26 KiB | Viewed 8201 times ]
Top
 Profile  
 
 Post subject: Re: Low Lag Snow(storm)
PostPosted: Mon Nov 21, 2011 1:56 am 
Furious Typer
User avatar

Joined: Sat Jul 16, 2011 3:35 pm
Posts: 164
W


Last edited by Wolf Paws on Wed Feb 29, 2012 8:01 pm, edited 1 time in total.

Top
 Profile  
 
 Post subject: Re: Low Lag Snow(storm)
PostPosted: Mon Nov 21, 2011 7:54 am 
OSG Elite
User avatar

Joined: Thu Aug 06, 2009 7:07 am
Posts: 338
Location: B.C. Canada
Thanks Oddy. That's my kind of snow storm.. Virtual!


Top
 Profile  
 
 Post subject: Re: Low Lag Snow(storm)
PostPosted: Mon Nov 21, 2011 4:18 pm 
Thank you! I set up 14 of these in Winter and I think the results are awesome. 8-)
{L_IMAGE}
{L_IMAGE}


Top
  
 
 Post subject: Re: Low Lag Snow(storm)
PostPosted: Mon Nov 21, 2011 4:48 pm 
OSG Elite

Joined: Wed Aug 05, 2009 1:59 am
Posts: 417
YW all!

Odd


Top
 Profile  
 
 Post subject: Re: Low Lag Snow(storm)
PostPosted: Sat Nov 26, 2011 5:53 pm 
User avatar

Joined: Tue Mar 29, 2011 11:47 am
Posts: 39
Thanks a lot Odd :-)

Houdoe en tot ziens

Tim

_________________
My virtual brain is like a williams pear in a bottle of brandy.


Top
 Profile  
 
 Post subject: Re: Low Lag Snow(storm)
PostPosted: Sat Nov 26, 2011 6:58 pm 
Furious Typer
User avatar

Joined: Mon Oct 25, 2010 7:42 pm
Posts: 234
Location: Canada
Oddy,

This rocks! I sent you a PM asking for advice on a snag but I might have just figured out what I misread:)

Jamie


Top
 Profile  
 
 Post subject: Re: Low Lag Snow(storm)
PostPosted: Sat Dec 03, 2011 5:11 pm 
Site Admin
User avatar

Joined: Sat Feb 02, 2008 5:27 pm
Posts: 843
here is a snow particle i made couple years ago for Wright Plaza.


Attachments:
snowflake_particles_02b.png
snowflake_particles_02b.png [ 64.17 KiB | Viewed 8039 times ]
Top
 Profile  
 
 Post subject: Re: Low Lag Snow(storm)
PostPosted: Sat Dec 03, 2011 9:19 pm 
Furious Typer
User avatar

Joined: Sat Jul 16, 2011 3:35 pm
Posts: 164
Nebadon Izumi {L_WROTE}:
here is a snow particle i made couple years ago for Wright Plaza.


Last edited by Wolf Paws on Wed Feb 29, 2012 7:59 pm, edited 1 time in total.

Top
 Profile  
 
 Post subject: Re: Low Lag Snow(storm)
PostPosted: Sun Dec 04, 2011 11:05 am 
OSG Elite

Joined: Wed Aug 05, 2009 1:59 am
Posts: 417
Thanks Neb.


Top
 Profile  
 
Display posts from previous:  Sort by  
Post a new topicPost a reply Page 1 of 2   [ 11 posts ]
Go to page 1, 2  Next


Who is online

Users browsing this forum: No registered users and 2 guests


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
cron


Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group
610nm Style by Daniel St. Jules of Gamexe.net