Change font size
It is currently Tue Dec 18, 2018 12:13 pm

Forum rules


{L_IMAGE}



Post a new topicPost a reply Page 1 of 1   [ 6 posts ]
Author Message
 Post subject: MultiWindlight enviroment
PostPosted: Sat Jul 07, 2012 1:37 am 

Joined: Tue Nov 16, 2010 7:45 am
Posts: 9
Uses lightshare and some osFunctions to setup a daynight cycle and vector specific windlight.

{L_CODE}:
// Artemis Tesla 2010-10-19

float gDefaultAngle = 0.317;                            // Time of day when script is off
rotation gDefaultColorSunMoon = <0.24,0.26,0.30,0.30>;  // Sun / Moon color when script is off

rotation gColorSun = <0.24,0.26,0.30,0.30>;             // Sun Color
rotation gColorMoon = <0.12, 0.13, 0.15, 0.15>;         // Moon color. I use half of Sun color

float gAtmosphereHeight = 1024.0;                       // Height above which avatars recieve WL space

integer gTides = FALSE;                                 // TRUE enables Tides
float gHighTide = 20.000;                               // Put your current water height here
float gTideOffsetMultiplier = 4.000;                    // 4.0 equals a tide offset of one decimetre
float gTideMultiplier = 4.000;                          // 4.0 equals a tidal range of one meter

// Keys of the objects you want to move with the tide
list gBoatKeys = [];

// key gAuthorisedKey = NULL_KEY;    // Key of Random World touch prim

// copy from your regions windlight settings excluding WL_SUN_MOON_POSITION and WL_SUN_MOON_COLOR.
list gWL = [
    WL_WATER_COLOR, <4,38,64>,
    WL_WATER_FOG_DENSITY_EXPONENT, 4.0,
    WL_UNDERWATER_FOG_MODIFIER, 0.25,
    WL_REFLECTION_WAVELET_SCALE, <2.0,2.0,2.0>,
    WL_FRESNEL_SCALE, 0.40,
    WL_FRESNEL_OFFSET, 0.50,
    WL_REFRACT_SCALE_ABOVE, 0.03,
    WL_REFRACT_SCALE_BELOW, 0.20,
    WL_BLUR_MULTIPLIER, 0.040,
    WL_BIG_WAVE_DIRECTION, <1.05,-0.42,0>,
    WL_LITTLE_WAVE_DIRECTION, <1.11,-1.16,0>,
    WL_NORMAL_MAP_TEXTURE, "822ded49-9a6c-f61c-cb89-6df54f42cdf4",
    WL_HORIZON, <0.25,0.25,0.32,0.32>,
    WL_HAZE_HORIZON, 0.19,
    WL_BLUE_DENSITY, <0.12,0.22,0.38,0.38>,
    WL_HAZE_DENSITY, 0.70,
    WL_DENSITY_MULTIPLIER, 0.18,
    WL_DISTANCE_MULTIPLIER, 0.8,
    WL_MAX_ALTITUDE, 1605,
    WL_AMBIENT, <0.35,0.35,0.35,0.35>,
    WL_EAST_ANGLE, 0.00,
    WL_SUN_GLOW_FOCUS, 0.10,
    WL_SUN_GLOW_SIZE, 1.75,
    WL_SCENE_GAMMA, 1.00,
    WL_STAR_BRIGHTNESS, 0.00,
    WL_CLOUD_COLOR, <0.41,0.41,0.41,0.41>,
    WL_CLOUD_XY_DENSITY, <1.00,0.53,1.0>,
    WL_CLOUD_COVERAGE, 0.27,
    WL_CLOUD_SCALE, 0.42,
    WL_CLOUD_DETAIL_XY_DENSITY, <1.00,0.53,0.12>,
    WL_CLOUD_SCROLL_X, 0.20,
    WL_CLOUD_SCROLL_Y, 0.01,
    WL_DRAW_CLASSIC_CLOUDS, TRUE,
    WL_CLOUD_SCROLL_X_LOCK, FALSE,
    WL_CLOUD_SCROLL_Y_LOCK, FALSE];

// Space Example
list gSceneSpace = [
    WL_WATER_COLOR, <0, 0, 0>,
    WL_WATER_FOG_DENSITY_EXPONENT, 0.0,
    WL_UNDERWATER_FOG_MODIFIER, 0.0,
    WL_REFLECTION_WAVELET_SCALE, <0.0, 0.0, 0.0>,
    WL_FRESNEL_SCALE, 0.0,
    WL_FRESNEL_OFFSET, 0.0,
    WL_REFRACT_SCALE_ABOVE, 0.0,
    WL_REFRACT_SCALE_BELOW, 0.0,
    WL_BLUR_MULTIPLIER, 0.0,
    WL_BIG_WAVE_DIRECTION, <0.0, 0.0, 0.0>,
    WL_LITTLE_WAVE_DIRECTION, <0.0, 0.0, 0.0>,
    WL_NORMAL_MAP_TEXTURE, "5748decc-f629-461c-9a36-a35a221fe21f",
    WL_HORIZON, <0.0, 0.0, 0.0, 0.0>,
    WL_HAZE_HORIZON, 0.0,
    WL_BLUE_DENSITY, <0.0, 0.0, 0.0, 0.0>,
    WL_HAZE_DENSITY, 0.0,
    WL_DENSITY_MULTIPLIER, 0.0,
    WL_DISTANCE_MULTIPLIER, 0.0,
    WL_MAX_ALTITUDE, 0,
    WL_SUN_MOON_POSITION, 0.000,
    WL_SUN_MOON_COLOR, <0.0, 0.0, 0.0, 0.0>,
    WL_AMBIENT, <0.0, 0.0, 0.0, 0.0>,
    WL_EAST_ANGLE, 0.00,
    WL_SUN_GLOW_FOCUS, 0.15,
    WL_SUN_GLOW_SIZE, 1.75,
    WL_SCENE_GAMMA, 0.6,
    WL_STAR_BRIGHTNESS, 2.0,
    WL_CLOUD_COLOR, <0.0, 0.0, 0.0, 0.0>,
    WL_CLOUD_XY_DENSITY, <0.0, 0.0, 0.0>,
    WL_CLOUD_COVERAGE, 0.0,
    WL_CLOUD_SCALE, 0.01,
    WL_CLOUD_DETAIL_XY_DENSITY, <0.00, 0.00, 0.00>,
    WL_CLOUD_SCROLL_X, 0.00,
    WL_CLOUD_SCROLL_Y, 0.00,
    WL_DRAW_CLASSIC_CLOUDS, FALSE,
    WL_CLOUD_SCROLL_X_LOCK, FALSE,
    WL_CLOUD_SCROLL_Y_LOCK, FALSE];


// Indoor WL
// Requires an if bounding box to be setup in Check Avatar Position
/*
list gSceneIndoors = [
    WL_WATER_COLOR, <4,38,64>,
    WL_WATER_FOG_DENSITY_EXPONENT, 4.0,
    WL_UNDERWATER_FOG_MODIFIER, 0.25,
    WL_REFLECTION_WAVELET_SCALE, <2.0,2.0,2.0>,
    WL_FRESNEL_SCALE, 0.40,
    WL_FRESNEL_OFFSET, 0.50,
    WL_REFRACT_SCALE_ABOVE, 0.03,
    WL_REFRACT_SCALE_BELOW, 0.20,
    WL_BLUR_MULTIPLIER, 0.040,
    WL_BIG_WAVE_DIRECTION, <1.05,-0.42,0>,
    WL_LITTLE_WAVE_DIRECTION, <1.11,-1.16,0>,
    WL_NORMAL_MAP_TEXTURE, "822ded49-9a6c-f61c-cb89-6df54f42cdf4",
    WL_HORIZON, <0.25,0.25,0.32,0.32>,
    WL_HAZE_HORIZON, 0.19,
    WL_BLUE_DENSITY, <0.12,0.22,0.38,0.38>,
    WL_HAZE_DENSITY, 0.70,
    WL_DENSITY_MULTIPLIER, 0.18,
    WL_DISTANCE_MULTIPLIER, 0.8,
    WL_MAX_ALTITUDE, 1605,
    // Set to 0.0 or 0.5 so the sun / moon does not effect your lightning
    WL_SUN_MOON_POSITION, 0.500,
    WL_SUN_MOON_COLOR, <0.24, 0.26, 0.30, 0.30>,
    WL_AMBIENT, <0.35,0.35,0.35,0.35>,
    WL_EAST_ANGLE, 0.00,
    WL_SUN_GLOW_FOCUS, 0.10,
    WL_SUN_GLOW_SIZE, 1.75,
    WL_SCENE_GAMMA, 1.00,
    WL_STAR_BRIGHTNESS, 0.00,
    WL_CLOUD_COLOR, <0.41,0.41,0.41,0.41>,
    WL_CLOUD_XY_DENSITY, <1.00,0.53,1.0>,
    WL_CLOUD_COVERAGE, 0.27,
    WL_CLOUD_SCALE, 0.42,
    WL_CLOUD_DETAIL_XY_DENSITY, <1.00,0.53,0.12>,
    WL_CLOUD_SCROLL_X, 0.20,
    WL_CLOUD_SCROLL_Y, 0.01,
    WL_DRAW_CLASSIC_CLOUDS, TRUE,
    WL_CLOUD_SCROLL_X_LOCK, FALSE,
    WL_CLOUD_SCROLL_Y_LOCK, FALSE];
*/

//--------------------------------------------------------------------------------------

integer gOn = FALSE;
integer gTick = 0;
integer gTickRandomWorld = 3;
integer gBoats = 0;
float gAngle = 0.0;
float gTide = 0.0;
key gOwner = NULL_KEY;
list gRandomWorld = [];
list gScene = [];
rotation gColorSunMoon = ZERO_ROTATION;
string gOwnerName = "";
string gText = "";

update()
{
    gText = "Multi WL Environment\nState: On\nAngle: " + (string)gAngle;
   
    if (gAngle >= 0.000 & gAngle <= 0.499) { gColorSunMoon = gColorSun; }
    if (gAngle >  0.499 & gAngle <= 0.999) { gColorSunMoon = gColorMoon; }
   
    gScene = gWL+ [WL_SUN_MOON_POSITION, gAngle, WL_SUN_MOON_COLOR, gColorSunMoon];
   
/*
        gTickRandomWorld++;
        if (gTickRandomWorld > 3)
        {
            gTickRandomWorld = 0;
            gRandomWorld = generateRandomWorld();
        }
*/
   
    if (gTides)
    {
        float tidalForce;
        float tideOffset;
   
        if (gAngle >= 0.000 & gAngle <= 0.499) { tidalForce = 0.249; tideOffset = 0.000; }
        if (gAngle >  0.499 & gAngle <= 0.999) { tidalForce = 0.749; tideOffset = 0.025; }
   
        gTide = gHighTide - (llFabs((tidalForce - gAngle) * gTideMultiplier)
            + (tideOffset * gTideOffsetMultiplier));
   
        osSetRegionWaterHeight(gTide);
        if (gBoats) updateBoats(gTide);
   
        gText = gText + "\nTide: " + (string)gTide + " Boats: " + (string)gBoats;
    }
}

updateBoats(float tide)
{
    integer boat = 0;
    integer boats = llGetListLength(gBoatKeys);
   
    for (; boat < boats; boat++)
    {
        osMessageObject(llList2Key(gBoatKeys, boat), (string)tide);       
    }
}

rotation high2Fourth(float first, float second, float third)
{
    float fourth = 0.0;
   
    if (first > second)
    {
        if (first > third) fourth = first;
        else fourth = third;
    }
    else
    {
        if (second > third) fourth = second;
        else fourth = third;
    }
   
    return <first, second, third, fourth>;
}

// Random WL
// Requires an if bounding box to be setup in Check Avatar Position
/*
list generateRandomWorld()
{
    return [
        WL_WATER_COLOR, <(integer)llFrand(255.99999),
                         (integer)llFrand(255.99999),
                         (integer)llFrand(255.99999)>,
        WL_WATER_FOG_DENSITY_EXPONENT, llFrand(10.0),
        WL_UNDERWATER_FOG_MODIFIER, llFrand(2.0),
        WL_REFLECTION_WAVELET_SCALE, <llFrand(10.0), llFrand(10.0), llFrand(10.0)>,
        WL_FRESNEL_SCALE, llFrand(1.0),
        WL_FRESNEL_OFFSET, llFrand(1.0),
        WL_REFRACT_SCALE_ABOVE, llFrand(1.0),
        WL_REFRACT_SCALE_BELOW, llFrand(1.0),
        WL_BLUR_MULTIPLIER, llFrand(0.160),
        WL_BIG_WAVE_DIRECTION, <llFrand(8.0) - 4, llFrand(8.0) - 4, 0.0>,
        WL_LITTLE_WAVE_DIRECTION, <llFrand(8.0) - 4, llFrand(8.0) - 4, 0.0>,
        WL_NORMAL_MAP_TEXTURE, "822ded49-9a6c-f61c-cb89-6df54f42cdf4",
        WL_HORIZON, high2Fourth(llFrand(1.0), llFrand(1.0), llFrand(1.0)),
        WL_HAZE_HORIZON, llFrand(1.0),
        WL_BLUE_DENSITY, high2Fourth(llFrand(1.0), llFrand(1.0), llFrand(1.0)),
        WL_HAZE_DENSITY, llFrand(4.0),
        WL_DENSITY_MULTIPLIER,llFrand(0.9),
        WL_DISTANCE_MULTIPLIER, llFrand(100.0),
        WL_MAX_ALTITUDE, (integer)llFrand(4000.99),
        WL_SUN_MOON_COLOR, high2Fourth(llFrand(1.0), llFrand(1.0), llFrand(1.0)),
        WL_AMBIENT, high2Fourth(llFrand(1.0), llFrand(1.0), llFrand(1.0)),
        WL_EAST_ANGLE, llFrand(1.0),
        WL_SUN_GLOW_FOCUS, llFrand(0.5),
        WL_SUN_GLOW_SIZE, llFrand(1.99),
        WL_SCENE_GAMMA, llFrand(10.0),
        WL_STAR_BRIGHTNESS, llFrand(2.0),
        WL_CLOUD_COLOR, high2Fourth(llFrand(1.0), llFrand(1.0), llFrand(1.0)),
        WL_CLOUD_XY_DENSITY, <llFrand(1.0), llFrand(1.0), llFrand(1.0)>,
        WL_CLOUD_COVERAGE, llFrand(1.0),
        WL_CLOUD_SCALE, llFrand(1.0),
        WL_CLOUD_DETAIL_XY_DENSITY, <llFrand(1.0), llFrand(1.0), llFrand(1.0)>,
        WL_CLOUD_SCROLL_X, llFrand(20.0) - 10,
        WL_CLOUD_SCROLL_Y, llFrand(20.0) - 10,
        WL_CLOUD_SCROLL_Y_LOCK, (integer)llFrand(1.99999),
        WL_CLOUD_SCROLL_X_LOCK, (integer)llFrand(1.99999),
        WL_DRAW_CLASSIC_CLOUDS, FALSE,
        WL_SUN_MOON_POSITION, llFrand(1.0)
    ];
}
*/

default
{
    on_rez(integer rezed) { do { llSay(0, "Resetting..."); llResetScript(); } while (TRUE); }
   
    state_entry()
    {
        gOwner = llGetOwner();
        gOwnerName = llKey2Name(gOwner);
        gText = "Multi WL Environment\nState: Off";
        gBoats = llGetListLength(gBoatKeys);
       
        llSetText(gText,<1.0,1.0,1.0>,1.0);
        llTargetOmega(<0,-00.09,-00.09>,PI,-0.09);
    }
   
    touch_start(integer touched)
    {
        if(llDetectedKey(0) == gOwner)
        {
            gOn = !gOn;
                   
            if (gOn)
            {
                llSetTimerEvent(0.9);
                string angle = (string)(llGetTimeOfDay() / 14400);
                gAngle  = (float)llGetSubString(angle, 0, llSubStringIndex(angle,".") + 3);
               
                update();       
            }
            else
            {
                llSetTimerEvent(0.0);
                lsSetWindlightScene(gWL + [WL_SUN_MOON_POSITION, gDefaultAngle,
                                           WL_SUN_MOON_COLOR, gDefaultColorSunMoon]);
               
                gText = "Multi WL Environment\nState: Off";
                if (gTides)
                {
                    osSetRegionWaterHeight(gHighTide);
                    if (gBoats) updateBoats(gHighTide);
                }
               
                gTick = 0;
                gTickRandomWorld = 0;
            }
           
            llSetText(gText,<1.0,1.0,1.0>,1.0);
        }
    }
   
/*       
    dataserver( key queryID, string data )
    {
        if (queryID == gAuthorisedKey)
        {
             llInstantMessage(data, llDumpList2String(gRandomWorld,", "));
        }
    }
*/   
   
    timer()
    {
        gTick++;

        // 0.9 * 16 = 14.4 * 1000 = 144000 or the number of seconds in 4 hours or 1 SL day
        if (gTick > 15)
        {
            gTick = 0;

            gAngle = gAngle + 0.001;
            if (gAngle > 0.999) { gAngle = 0.000; }
           
            update();
        }
       
        list avatarList = osGetAgents();
        list avatarListData = osGetAvatarList();

        if (avatarList != [])
        {
            integer avatars = llGetListLength(avatarList);
            integer avatar = 0;   

            key avatarKey = NULL_KEY;
            vector avatarPosition = ZERO_VECTOR;
            string avatarName = "";
           
            string text = "";

            if (llListFindList(avatarList, [gOwnerName]))
            {
                avatarPosition = llList2Vector(llGetObjectDetails(gOwner, [OBJECT_POS]), 0);
                avatarListData = [gOwner, avatarPosition, gOwnerName] + avatarListData;
            }
           
            for (; avatar < avatars; ++avatar)
            {
                avatarKey = llList2Key(avatarListData,(avatar * 3));
                avatarPosition = llList2Vector(avatarListData,((avatar * 3) + 1));
                avatarName = llList2String(avatarListData,((avatar * 3) + 2));
               
               
                // Check Avatar Position
                if (avatarPosition.z <= gAtmosphereHeight)
                {
// Example if bounding box
/*                       
                    if (avatarPosition.x >= 80.000 & avatarPosition.x <= 90.000 &
                        avatarPosition.y >= 80.000 & avatarPosition.y <= 90.000 &
                        avatarPosition.z >= 20.000 & avatarPosition.z <= 30.000)
                    {
                        lsSetWindlightSceneTargeted(gRandomWorld, avatarKey);
                    }
                    else
                    {
*/
// Example if bounding box
/*                       
                        if (avatarPosition.x >= 130.000 & avatarPosition.x <= 140.000 &
                            avatarPosition.y >= 130.000 & avatarPosition.y <= 140.000 &
                            avatarPosition.z >=  21.000 & avatarPosition.z <=  31.000)
                        {
                            lsSetWindlightSceneTargeted(gSceneIndoors, avatarKey);
                        }
                       
                        else
*/
                    lsSetWindlightSceneTargeted(gScene, avatarKey);
//                    }
                }
                else
                {
                    lsSetWindlightSceneTargeted(gSceneSpace, avatarKey);
                }
                text = text + "\n" + avatarName;
            }
            llSetText(gText + text, <1.0,1.0,1.0>, 1.0);
        }
    }
}


Top
 Profile  
 
 Post subject: Re: MultiWindlight enviroment
PostPosted: Fri Nov 08, 2013 1:36 pm 

Joined: Wed Jul 24, 2013 5:22 am
Posts: 5
Sounds great but if I use this how can I get back to normal? :roll:

I found a box at Pathlandia that gave me a gloomy windlight setting when clicked. I used it for Halloween but cannot get rid of that effect again. :o


Top
 Profile  
 
 Post subject: Re: MultiWindlight enviroment
PostPosted: Sun Nov 10, 2013 7:28 pm 
Furious Typer
User avatar

Joined: Fri Mar 26, 2010 12:11 pm
Posts: 147
Location: Belgium / Brussels
Default LightShare Script
{L_CODE}:
default
{
    state_entry()
    {
        lsSetWindlightScene([
            WL_WATER_COLOR, <4,38,64>,
            WL_WATER_FOG_DENSITY_EXPONENT, 4.0,
            WL_UNDERWATER_FOG_MODIFIER, 0.25,

            WL_REFLECTION_WAVELET_SCALE, <2.0,2.0,2.0>,
            WL_FRESNEL_SCALE, 0.40,
            WL_FRESNEL_OFFSET, 0.50,

            WL_REFRACT_SCALE_ABOVE, 0.03,
            WL_REFRACT_SCALE_BELOW, 0.20,
            WL_BLUR_MULTIPLIER, 0.040,

            WL_BIG_WAVE_DIRECTION, <1.05,-0.42,0>,
            WL_LITTLE_WAVE_DIRECTION, <1.11,-1.16,0>,

            WL_NORMAL_MAP_TEXTURE, "822ded49-9a6c-f61c-cb89-6df54f42cdf4",

            WL_HORIZON, <0.25,0.25,0.32,0.32>,
            WL_HAZE_HORIZON, 0.19,

            WL_BLUE_DENSITY, <0.12,0.22,0.38,0.38>,
            WL_HAZE_DENSITY, 0.70,

            WL_DENSITY_MULTIPLIER, 0.18,
            WL_DISTANCE_MULTIPLIER, 0.8,
            WL_MAX_ALTITUDE, 1605,

            WL_SUN_MOON_POSITION, 0.317,
            WL_SUN_MOON_COLOR, <0.24,0.26,0.30,0.30>,
            WL_AMBIENT, <0.35,0.35,0.35,0.35>,
            WL_EAST_ANGLE, 0.00,

            WL_SUN_GLOW_FOCUS, 0.10,
            WL_SUN_GLOW_SIZE, 1.75,
            WL_SCENE_GAMMA, 1.00,
            WL_STAR_BRIGHTNESS, 0.00,

            WL_CLOUD_COLOR, <0.41,0.41,0.41,0.41>,
            WL_CLOUD_XY_DENSITY, <1.00,0.53,1.0>,

            WL_CLOUD_COVERAGE, 0.27,
            WL_CLOUD_SCALE, 0.42,
            WL_CLOUD_DETAIL_XY_DENSITY, <1.00,0.53,0.12>,

            WL_CLOUD_SCROLL_X, 0.20,
            WL_CLOUD_SCROLL_Y, 0.01,
            WL_DRAW_CLASSIC_CLOUDS, TRUE,
            WL_CLOUD_SCROLL_X_LOCK, FALSE,
            WL_CLOUD_SCROLL_Y_LOCK, FALSE
        ]);
    }
}

_________________
Webmaster @ digitalconcepts.free.fr & digigrids.free.fr


Top
 Profile  
 
 Post subject: Re: MultiWindlight enviroment
PostPosted: Tue Nov 12, 2013 6:01 am 

Joined: Wed Jul 24, 2013 5:22 am
Posts: 5
Thanks a lot!!! Would that mean that if I put this script in an object and klick on it, that will restore the default Windlight settings and default daycycle to my region permanently ????????


Top
 Profile  
 
 Post subject: Re: MultiWindlight enviroment
PostPosted: Tue Nov 12, 2013 4:06 pm 
Furious Typer
User avatar

Joined: Fri Mar 26, 2010 12:11 pm
Posts: 147
Location: Belgium / Brussels
This param put the sun at te default place but isn't really the "day cycle".
{L_CODE}:
WL_SUN_MOON_POSITION, 0.317,
WL_EAST_ANGLE, 0.00,

Paramettres other hand all values ​​by default LightShare.

I can not remember if Lightshare adjusts the "Day Cycle". I do not think so. "Day Cycle" is paramettre of Windlight, not LightShare.

To my knowledge, only Aurora-Sim currently adjusts the "real" paramettres Windlight "day cycle" with unique function features (not available in second life either)

Lsl allow this: http://wiki.secondlife.com/wiki/LlGetSunDirection
And a feature request is: http://wiki.secondlife.com/wiki/LlSetSunDirection

You can use OSSL function too ... (Threat Level: Nuisance).
{L_CODE}:
default
{
    state_entry( )
    {
        osSetRegionSunSettings(FALSE, TRUE, 12.0);
    }
}

_________________
Webmaster @ digitalconcepts.free.fr & digigrids.free.fr


Last edited by dj phil on Sun Dec 29, 2013 5:46 pm, edited 1 time in total.

Top
 Profile  
 
 Post subject: Re: MultiWindlight enviroment
PostPosted: Fri Nov 22, 2013 12:40 am 
Furious Typer
User avatar

Joined: Fri Mar 26, 2010 12:11 pm
Posts: 147
Location: Belgium / Brussels
You can also use:
{L_CODE}:
default
{
    state_entry()
    {
        lsClearWindlightScene();
    }
}

:P

_________________
Webmaster @ digitalconcepts.free.fr & digigrids.free.fr


Top
 Profile  
 
Display posts from previous:  Sort by  
Post a new topicPost a reply Page 1 of 1   [ 6 posts ]


Who is online

Users browsing this forum: No registered users and 1 guest


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  
cron


Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group
610nm Style by Daniel St. Jules of Gamexe.net