Change font size
It is currently Wed Aug 15, 2018 1:17 pm

Forum rules


{L_IMAGE}
. please keep questions related to an OpenSimulator and OSgrid nature.



Post a new topicPost a reply Page 1 of 1   [ 9 posts ]
Author Message
 Post subject: finding an object from UUID number
PostPosted: Tue Jul 27, 2010 12:06 pm 

Joined: Mon Dec 08, 2008 12:17 pm
Posts: 35
Location: Northern Michigan
My monitor outputs the following message every couple of minutes:

12:59:50 - [SCENE]: Storing Primitive, 6d0f3a25-68e0-4501-a179-8c8132c0c824 in Fro
12:59:50 - [REGION DB]: Adding obj: 6d0f3a25-68e0-4501-a179-8c8132c0c824 to region: 098b6a43-a802-488f-b449-e055f7b33a41

My question is, how can I determine which object this is from the UUID on my monitor. I suspect perhaps a script at work, but really don't know.


Top
 Profile  
 
 Post subject: Re: finding an object from UUID number
PostPosted: Tue Jul 27, 2010 1:03 pm 
Site Admin
User avatar

Joined: Sat Feb 02, 2008 5:27 pm
Posts: 843
you will need to search the prims table inside of the database.


Top
 Profile  
 
 Post subject: Re: finding an object from UUID number
PostPosted: Tue Jul 27, 2010 4:20 pm 

Joined: Mon Dec 08, 2008 12:17 pm
Posts: 35
Location: Northern Michigan
Thanks, Neb. Not sure how to get inside the database, but have another resource to ask before I post on the forums. Cro


Top
 Profile  
 
 Post subject: Re: finding an object from UUID number
PostPosted: Tue Jul 27, 2010 9:47 pm 

Joined: Mon Dec 08, 2008 12:17 pm
Posts: 35
Location: Northern Michigan
My other resource suggested looking in the mysql data base - easier said than done - can you steer me a bit more? Where is the data base? What is it called, exactly? I'm running mono on an iMac. Thanks for any info.


Top
 Profile  
 
 Post subject: Re: finding an object from UUID number
PostPosted: Wed Jul 28, 2010 12:58 am 
Furious Typer
User avatar

Joined: Fri Jul 17, 2009 5:57 am
Posts: 142
Location: Germany
If you are using MySQL with your OpenSim setup, then use this on a command line:
{L_CODE}:
echo "SELECT Name, GroupPositionX 'Position X', GroupPositionY 'Position Y', GroupPositionZ 'Position Z', RegionUUID FROM prims WHERE UUID='6d0f3a25-68e0-4501-a179-8c8132c0c824';" | mysql -u opensimuser -p opensimdb

You must replace opensimuser with the actual user ID that you use to access the database, and opensimdb with the actual database name. You find both in OpenSim.ini; check out the configuration parameter storage_connection_string for this (the defaults for both are "opensim"). You will also be asked for opensimuser's password.

If you are using SQLite, then use this on a command line in the bin directory of your OpenSim installation:
{L_CODE}:
sqlite3 -column -header OpenSim.db "SELECT Name, GroupPositionX 'Position X', GroupPositionY 'Position Y', GroupPositionZ 'Position Z', RegionUUID FROM prims WHERE UUID='6d0f3a25-68e0-4501-a179-8c8132c0c824';"

If you do not have the sqlite3 tool installed, then you can get it from http://www.sqlite.org/download.html.

Both commands will show you the name, coordinates, and the region of the prim. The region is given as an UUID. Look into your region configuration files in folder bin/Regions to find out the name of the region with that UUID. (You can omit this last step because you are already told the region name in the logging output.)


Top
 Profile  
 
 Post subject: Re: finding an object from UUID number
PostPosted: Wed Jul 28, 2010 6:16 am 
OSG Elite
User avatar

Joined: Thu Aug 06, 2009 7:07 am
Posts: 338
Location: B.C. Canada
I use Toad for MySQL from Quest software to access my MySQL database.
http://www.quest.com/toad-for-mysql/


Top
 Profile  
 
 Post subject: Re: finding an object from UUID number
PostPosted: Wed Jul 28, 2010 10:54 am 
OSG Elite
User avatar

Joined: Wed Mar 11, 2009 3:57 pm
Posts: 444
You can always use this little LSL Script I just whipped up for this purpose. It's pretty straight forward. Nothing Fancy, it's simple and requires no DataBase Diving

1) Put Script in a prim (located on Same Region which you want to search on)
2) Touch to Activate (uses Channel 66 by Default)
3) In Chat Line type /66 UUID
where UUID is the UUID of the Object your wish to Locate & get info On

{L_CODE}:
integer CHANNEL = 66;    //Change this if you want to use another channel, OpenChat = 0 (avoid that)
integer ListenHandle;
key OWNER;
//
ObjInfo(key lostuuid)
{
    list a = llGetObjectDetails(lostuuid, ([OBJECT_NAME,
                OBJECT_DESC, OBJECT_POS, OBJECT_ROT, OBJECT_VELOCITY,
                OBJECT_OWNER, OBJECT_GROUP, OBJECT_CREATOR]));
            llInstantMessage(OWNER,"INFO REQUESTED:"+
              "\n\tUUID: "+ (string)lostuuid +
              "\n\tName: \""       + llList2String(a,0) + "\"" +
              "\n\tDescription: \"" + llList2String(a,1) + "\"" +
              "\n\tPosition: "     + llList2String(a,2) +
              "\n\tRotation: "     + llList2String(a,3) +
              "\n\tVelocity: "     + llList2String(a,4) +
              "\n\tOwner: "        + llList2String(a,5) +
              "\n\tGroup: "        + llList2String(a,6) +
              "\n\tCreator: "      + llList2String(a,7));
}
//
Info()
{
    llInstantMessage(OWNER, "--- USAGE INFO ---\n"+
        "\tTouch to Open Channel "+(string)CHANNEL+" to Listen for Object UUID\n"+
        "\tChannel "+(string)CHANNEL+" Listen will be closed IMMEDIATELY After Owner enters UUID for Object\n"+
        "\tTouch Again to Enter a New UUID\n"+
        "\tNOTE:       Use PRIM-UUID -NOT- SCRIPT-UUID as shown in OpenSim LOG or Console Output\n"+
        "\tSuggested:  Copy-Paste of UUID to prevent errors");
}
default
{
    state_entry()
    {
        OWNER = llGetOwner();
        Info();
    }
    touch_end(integer num_detected)
    {
        key User =llDetectedKey(0);
        if(User != OWNER) return;            // ONLY OWNER USE

        llListenRemove(ListenHandle);        // SAFETY Kill CHANNEL incase left over
        ListenHandle = llListen(CHANNEL, "", OWNER, "");    // listen for dialog answers
        llInstantMessage(User, "Chat Listener ACTIVE on Channel "+(string)CHANNEL+": type in the Object UUID you wish information on");
    }
    listen( integer channel, string name, key id, string msg )
    {
        if(id == llGetOwner())
        {
            llListenRemove(ListenHandle); // Kill Listen Lag Reducer !
            llInstantMessage(id,"Chat Listener on "+(string)CHANNEL+" DEACTIVATED  ! Touch to ReEnable\nReceived Owner Input : "+msg);
            ObjInfo((key) msg);
        }
        else return;
    }
}


Good Luck, Hope it Helps.

_________________
No further support of any kind, for any of my materials. Use as/is whereis.
PLEASE UNSTICKY Any Stickied Posting by myself.


Top
 Profile  
 
 Post subject: Re: finding an object from UUID number
PostPosted: Wed Jul 28, 2010 7:49 pm 

Joined: Mon Dec 08, 2008 12:17 pm
Posts: 35
Location: Northern Michigan
What a cool script! Just the ticket for my problem w/o getting to deep in DB issues. It turned out to be some big goofy prim that I made physical and on the very edge of my region. Of course, it was named "prim", but I found it by location pretty quickly. TY so much.!


Top
 Profile  
 
 Post subject: Re: finding an object from UUID number
PostPosted: Fri Oct 01, 2010 2:23 pm 
Furious Typer

Joined: Fri Dec 04, 2009 11:59 am
Posts: 52
Thank you! Very Handy!


Top
 Profile  
 
Display posts from previous:  Sort by  
Post a new topicPost a reply Page 1 of 1   [ 9 posts ]


Who is online

Users browsing this forum: No registered users and 1 guest


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Jump to:  


Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group
610nm Style by Daniel St. Jules of Gamexe.net